////
Licensed to the Apache Software Foundation (ASF) under one
or more contributor license agreements.  See the NOTICE file
distributed with this work for additional information
regarding copyright ownership.  The ASF licenses this file
to you under the Apache License, Version 2.0 (the
"License"); you may not use this file except in compliance
with the License.  You may obtain a copy of the License at

https://www.apache.org/licenses/LICENSE-2.0

Unless required by applicable law or agreed to in writing,
software distributed under the License is distributed on an
"AS IS" BASIS, WITHOUT WARRANTIES OR CONDITIONS OF ANY
KIND, either express or implied.  See the License for the
specific language governing permissions and limitations
under the License.
////

Criteria is an advanced way to query that uses a Groovy builder to construct potentially complex queries. It is a much better approach than building up query strings using a `StringBuilder`.

Criteria can be used either with the `createCriteria()` or `withCriteria(closure)` methods.

The builder uses Hibernate 7's Criteria API (based on JPA Criteria). The nodes on this builder map to GORM query constraints which are then translated into JPA Criteria predicates.

[source,groovy]
----
def c = Account.createCriteria()
def results = c.list {
    between("balance", 500, 1000)
    eq("branch", "London")
    or {
        like("holderFirstName", "Fred%")
        like("holderFirstName", "Barney%")
    }
    maxResults(10)
    order("holderLastName", "desc")
}
----

This criteria will select up to 10 `Account` objects in a List matching the following criteria:

* `balance` is between 500 and 1000
* `branch` is 'London'
* `holderFirstName` starts with 'Fred' or 'Barney'

The results will be sorted in descending order by `holderLastName`.

If no records are found with the above criteria, an empty List is returned.

[[HibernateCriteriaDSL]]
==== Hibernate Criteria DSL

In Hibernate 7, the criteria builder has been completely rewritten to leverage the JPA Criteria API. The `HibernateCriteriaBuilder` implements the GORM criteria DSL and provides seamless integration with Hibernate 7 features.

The DSL supports all standard GORM criteria methods such as `eq`, `ne`, `gt`, `lt`, `ge`, `le`, `between`, `like`, `ilike`, `in`, `isNull`, `isNotNull`, `isEmpty`, `isNotEmpty`, and more.

[source,groovy]
----
def results = Person.withCriteria {
    ilike('firstName', 'b%')
    or {
        ge('age', 18)
        isNull('parent')
    }
}
----

==== Conjunctions and Disjunctions


As demonstrated in the previous example you can group criteria in a logical OR using an `or { }` block:

[source,java]
----
or {
    between("balance", 500, 1000)
    eq("branch", "London")
}
----

This also works with logical AND:

[source,java]
----
and {
    between("balance", 500, 1000)
    eq("branch", "London")
}
----

And you can also negate using logical NOT:

[source,java]
----
not {
    between("balance", 500, 1000)
    eq("branch", "London")
}
----

All top level conditions are implied to be AND'd together.


==== Querying Associations


Associations can be queried by having a node that matches the property name. For example say the `Account` class had many `Transaction` objects:

[source,groovy]
----
class Account {
    ...
    static hasMany = [transactions: Transaction]
    ...
}
----

We can query this association by using the property name `transactions` as a builder node:

[source,java]
----
def c = Account.createCriteria()
def now = new Date()
def results = c.list {
    transactions {
        between('date', now - 10, now)
    }
}
----

The above code will find all the `Account` instances that have performed `transactions` within the last 10 days.
You can also nest such association queries within logical blocks:

[source,java]
----
def c = Account.createCriteria()
def now = new Date()
def results = c.list {
    or {
        between('created', now - 10, now)
        transactions {
            between('date', now - 10, now)
        }
    }
}
----

Here we find all accounts that have either performed transactions in the last 10 days OR have been recently created in the last 10 days.


==== Querying with Projections


Projections may be used to customise the results. Define a "projections" node within the criteria builder tree to use projections.

[source,java]
----
def c = Account.createCriteria()

def numberOfBranches = c.get {
    projections {
        countDistinct('branch')
    }
}
----

When multiple fields are specified in the projection, a List of values will be returned. A single value will be returned otherwise.

Common projections include `count`, `countDistinct`, `groupProperty`, `avg`, `min`, `max`, `sum`, `id`, and `property`.


==== SQL Restrictions


You can access Hibernate's SQL Restrictions capabilities.

[source,java]
----
def c = Person.createCriteria()

def peopleWithShortFirstNames = c.list {
    sqlRestriction "char_length(first_name) <= 4"
}
----

SQL Restrictions may be parameterized to deal with SQL injection vulnerabilities related to dynamic restrictions.

[source,java]
----
def c = Person.createCriteria()

def peopleWithShortFirstNames = c.list {
    sqlRestriction "char_length(first_name) < ? AND char_length(first_name) > ?", [maxValue, minValue]
}
----

NOTE: Note that the parameter there is SQL. The `first_name` attribute referenced in the example refers to the persistence model, not the object model like in HQL queries.

==== Setting Properties in the Criteria Instance


The builder allows setting properties that control how the query is executed.

[source,groovy]
----
import org.hibernate.FetchMode
...
def results = c.list {
    maxResults(10)
    firstResult(50)
    cache(true)
    readOnly(true)
    lock(true)
    fetchMode("aRelationship", FetchMode.JOIN)
}
----

If a node within the builder tree doesn't match a particular criterion it will attempt to set a property on the Criteria object itself. This allows full access to all the properties in the criteria.

==== Advanced Hibernate 7 Features

The Hibernate 7 criteria builder supports several advanced features:

* **Pessimistic Locking:** Use `lock(true)` to obtain a pessimistic write lock.
* **Query Caching:** Use `cache(true)` to enable query caching for the results.
* **Read-Only Mode:** Use `readOnly(true)` to disable dirty checking for loaded entities.
* **Fetch Mode:** Use `fetchMode("association", FetchMode.JOIN)` to specify Eager/Lazy fetching strategies.


==== Using Scrollable Results


You can use Hibernate's https://docs.hibernate.org/orm/7.0/javadocs/org/hibernate/ScrollableResults.html[ScrollableResults] feature by calling the scroll method:

[source,groovy]
----
def results = crit.scroll {
    maxResults(10)
}
def f = results.first()
def l = results.last()
def n = results.next()
def p = results.previous()

def future = results.scroll(10)
def accountNumber = results.getLong('number')
----

To quote the Hibernate documentation on ScrollableResults:

____
A result iterator that allows moving around within the results by arbitrary increments. The Query / ScrollableResults pattern is very similar to the JDBC PreparedStatement / ResultSet pattern and the semantics of methods of this interface are similar to the similarly named methods on ResultSet.
____

Contrary to JDBC, columns of results are numbered from zero.


==== Querying with Eager Fetching


In the section on eager and lazy fetching we discussed how to declaratively specify fetching to avoid the N+1 SELECT problem. However, this can also be achieved using a criteria query:

[source,groovy]
----
def criteria = Task.createCriteria()
def tasks = criteria.list{
    eq "assignee.id", task.assignee.id
    join 'assignee'
    join 'project'
    order 'priority', 'asc'
}
----

Notice the usage of the `join` method: it tells the criteria API to use a `JOIN` to fetch the named associations with the `Task` instances. It's probably best not to use this for one-to-many associations though, because you will most likely end up with duplicate results. Instead, use the `select` fetch mode:

[source,groovy]
----
import org.hibernate.FetchMode as FM
...
def results = Airport.withCriteria {
    eq "region", "EMEA"
    fetchMode "flights", FM.SELECT
}
----

Although this approach triggers a second query to get the `flights` association, you will get reliable results — even with the `maxResults` option.

NOTE: `fetchMode` and `join` are general settings of the query and can only be specified at the top-level, i.e. you cannot use them inside projections or association constraints.

An important point to bear in mind is that if you include associations in the query constraints, those associations will automatically be eagerly loaded. For example, in this query:

[source,groovy]
----
def results = Airport.withCriteria {
    eq "region", "EMEA"
    flights {
        like "number", "BA%"
    }
}
----

the `flights` collection would be loaded eagerly via a join even though the fetch mode has not been explicitly set.


==== Method Reference


If you invoke the builder with no method name such as:

[source,groovy]
----
c { ... }
----

The builder defaults to listing all the results and hence the above is equivalent to:

[source,groovy]
----
c.list { ... }
----

[format="csv", options="header"]
|===
Method,Description
*list*,This is the default method. It returns all matching rows.
*get*,Returns a unique result set i.e. just one row. The criteria has to be formed in a way that it only queries one row. This method is not to be confused with a limit to just the first row.
*scroll*,Returns a scrollable result set.
*listDistinct*,If subqueries or associations are used one may end up with the same row multiple times in the result set. This allows listing only distinct entities and is equivalent to `DISTINCT_ROOT_ENTITY` of the CriteriaSpecification class.
*count*,Returns the number of matching rows.
|===


==== Combining Criteria


You can combine multiple criteria closures in the following way:

[source,groovy]
----
def emeaCriteria = {
    eq "region", "EMEA"
}

def results = Airport.withCriteria {
    emeaCriteria.delegate = delegate
    emeaCriteria()
    flights {
        like "number", "BA%"
    }
}
----

This technique requires that each criteria must refer to the same domain class (i.e. `Airport`).
A more flexible approach is to use Detached Criteria, as described in the following section.
